*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSL1006AG_P v.20210910.txt
*  Product Name      	: JMSL1006AG (PDFN5x6-8L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 2.0
*  Release Date	: Sep 10, 2021
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL1006AG D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006

Vmonitor D 18 0
RD 18 1 0.0031
RS S 3 1E-006
RG G 17 1.75
CGS 3 G 2.59E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00344*(TEMP-25))+((-2.74874E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.75)}


VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 8E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak 2.19407E-9
.MODEL Cbreak CAP (C = 1 VC1 = -0.01861 VC2 = 9.9891E-5)

.model NMOS NMOS
+LEVEL = 3                        
+VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 2.3                     TOX = 8E-10                   NSUB = 3.55E15                
+KP = 200                      U0 = 424                      KAPPA = 0.1                   
+GAMMA = 0.3                   PHI = 0.52                    THETA = 0.119092              
+DELTA = 50                    

.model DCGD D
+CJO = 5.8E-10                 VJ = 44.4329                  M = 3.97                      

.model DSUB D
+IS = 3.159816E-12             N = 1.075                     RS = 2.4E-3                   
+BV = 108                      xti = 2.5                     
           

.model DLIM D
+IS = 1E-4                     
.ends JMSL1006AG

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
